Automatically uninstall "Google-Drive" (includes YouTube Video Link)

Started by Theo Gottwald, February 06, 2022, 10:43:08 AM

Previous topic - Next topic

0 Members and 1 Guest are viewing this topic.

Theo Gottwald

Using the CHROME-Browser seems to have the disadvantage that Google-Drive is generally installed without asking.
Uninstalling it is theoretically easy, but it looks they made it a bit more difficult intentionally.

Of course it can not be uninstalled while its running.
And because its automatically starting with Windows- its always running.
So you can never uninstall it without first killing the process.

I have recorded the process in a short video. Part I of the Video shows how to use the SPR Buttonbar for an Editing Task in "Help and Manual 8" which is my favourite Help-File Editor. The secons Part of  the video shows the Script for the Uninstallation of Google Drive.
"Robot assisted Work" and "Uninstalling Google Drive"

So Step 1 is "To kill the Process"
Step 2 is: To call the Uninstall.exe
But what is the process name?

First i wanted to know "Where is that executable and whats its name?"


' Locate the Google-Drive Window
STW.ct|ATL:|In Google Drive anmelden
$$PID=#pid#
' Get Data From "af" means window handle -> Filename
' so in $$EXE is now the Path and Filename of the Executable that has generated this window.
GDF.af|$$EXE
' BLB. - Before Last Backslash
BLB.$$EXE|$$PAA
' ALB -> After Last Backslash
ALB.$$EXE|$$FIN
' Show Name and Path of Executable that generated the Google-Drive Window
MBX.$$FIN $crlf$ $$PAA
' Open the Folder in Explorer so i can see all the Files.
EXS.$$PAA
ENR.



Ok then i wanted a automatic running Uninstallation that will also work with future versions of google Drive.


'#EXE:?path\
'#SPI:ForceWrite
' Locate Google-Drive Window
STW.ct|ATL:|In Google Drive anmelden
' Get Process-ID from this window
$$PID=#pid#
' Get Executable/Filename/Path from this window
GDF.af|$$EXE
' Split Path in Path and Filename
BLB.$$EXE|$$PAA
ALB.$$EXE|$$FIN

' End Google Drive Process
CPR.$$PID

' Run Uninstallation
' No Versionsnumber so its universal
EXU.Google Drive

' Klick first Button
STW.ct|#32770|Google Drive
SCW.nict|1|301|Button|{&NOTEXT:}
' Possible Mouse-Click Commands are: MLE. | MLC. | MLM. | MLI. | BCS. | BCS.
BCS.

' Klick second Button
STW.ct|#32770|Google Drive
SCW.nict|1|303|Button|{&NOTEXT:}
BCS.

ENR.
'===========================================================